>l.L.

  100REM DFS/NET/ANFS ROM Selector
  200REM Uses "FindROM" method to identify DNFS and ANFS
  300REM and ROM Status table to enable/disable
  400REM NOT FOR TUBE - OSRDRM call doesn't work
  450REMIFPAGE<&2800 PROCrelocate 
  460REMOSCLI"KEY10PAGE="+STR$PAGE+"|MOLD|MRUN|M"
  465*KEY10
  470DIM osb 4
  480input$="NDR"+CHR$27+CHR$13+CHR$9
  500REPEAT
  600CLS
  650PRINT"DFS/NET/ANFS Switcher"'
  700anfsrom=FNfindrom("Acorn ANFS 4.")
  800IFanfsrom=-1 PRINT"No ANFS ROM installed" ELSE PRINT"ANFS in ROM ";anfsrom:input$="A"+input$
  900dnfsrom=FNfindrom("DFS,NET")
 1000IFdnfsrom=-1 PRINT"No DNFS ROM installed":END ELSE PRINT"DNFS in ROM ";dnfsrom  
 1100anfsstatus=-1:dnfsstatus=-1  
 1200IFanfsrom>-1 anfsstatus=?(&DF0+anfsrom)  
 1300dnfsstatus=?(&DF0+dnfsrom)
 1400IFanfsrom>-1 THEN IF anfsstatus AND 2^7 PRINT"ANFS Disabled" ELSE IFanfsrom>-1 PRINT"ANFS Enabled" 
 1500IFdnfsstatus AND 2^7 PRINT"NFS Disabled" ELSE PRINT"NFS Enabled"
 1600IFdnfsstatus AND 2^6 PRINT"DFS Disabled" ELSE PRINT"DFS Enabled"
 1700PRINT"OSHWM is &";~FNoshwm
 1800PRINT'"Options:":IFanfsrom>-1 THENPRINT"A - Toggle ANFS status"
 1850PRINT"N - Toggle NFS status"
 1860PRINT"D - Toggle DFS status"
 1870PRINT"R - Reset"
 1880PRINT"RETURN or TAB to end"
 1900REPEATK%=GET 
 2000UNTILINSTR(input$,CHR$K%) 
 2100IFK%<65 PRINT:END ELSEPRINTCHR$K%
 2120IFK%=ASC"A" THEN ?(&DF0+anfsrom)=?(&DF0+anfsrom)EOR128 
 2130IFK%=ASC"N" THEN ?(&DF0+dnfsrom)=?(&DF0+dnfsrom)EOR128
 2140IFK%=ASC"D" THEN ?(&DF0+dnfsrom)=?(&DF0+dnfsrom)EOR64 
 2150IFK%=ASC"R" THENOSCLI"KEY10PAGE="+STR$PAGE+"|MOLD|MRUN|M":CALL!-4
 2200UNTIL0
 2300DEFFNfindrom(title$)
 2400?&F7=&80:REM High byte of ROM Addr
 2500Y%=15:REM Starting ROM number
 2600REPEAT
 2700R%=TRUE
 2800?&F6=9:REM Low byte, start of ROM title
 2900REPEAT
 3000byte=USR&FFB9 AND 255
 3100IFbyte=ASC(MID$(title$,?&F6-8,1)) ELSE R%=FALSE
 3200?&F6=?&F6+1
 3300UNTILR%=FALSE OR ?&F6>8+LENtitle$
 3400IFR% THEN UNTILTRUE:=Y%
 3500Y%=Y%-1
 3600UNTILY%<0
 3700=-1
 3800DEFFNoshwm
 3810A%=131
 3820!osb=USR&FFF4
 3830=osb?1+(osb?2)*256
 4000DEFPROCrelocate
 4020FORB%=0 TO (TOP-PAGE)STEP4
 4030&2800!B%=PAGE!B%
 4040NEXT
 4050*KEY0PAGE=&2800|MOLD|MRUN|M
 4060*FX138,0,128
 4070END
 4080ENDPROC
>*SPOOL